***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 26, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PE4728L1Q-AU  A K 
.param
+vc0 = 1.050e-10          vc1 = 1.000e-12        vc2 = 8.000e-1	 	 vc3 = 1.000e-13	vc4 = 2.450e-1
+tc1 = 8.000e-3           tc2 = 1.000e-4	 tc3 = 8.000e-3  	 tc4 = 4.500e-2
d1 A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {4.199e-1*min(i,0)}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.282e-14	     n = 1.048            rs = 1.261e-02
+ibv = 1.0e-3		   nbv = 1.0		  bv = 32.75
+ikf = 1.317            
***** capacitance parameter *****
+cjo = 1.939e-10	     m = 3.535e-1	  vj = 6.882e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		    eg = 1.150	         xti = 3
+tikf = 1.000e-4          trs1 = 2.000e-3
+tbv1 = 8.710e-4	  tbv2 = -2.463e-7
.ends PE4728L1Q-AU
*$
